{--------------------------------------------------------}
{           envia uma informacao para a rede
{--------------------------------------------------------}

unit pprede;
interface
uses dvwin, dvcrt, winsock, dvinet, mmsystem,
     winprocs, wintypes, dvgrav, strings,
     ppvars, ppmsg;

function enviaRede (tipoInfo: byte; buffer: pchar; tam: word): boolean;
procedure informaIp;

implementation

{--------------------------------------------------------}
{               envia um buffer para a rede
{--------------------------------------------------------}

function enviaRede (tipoInfo: byte; buffer: pchar; tam: word): boolean;
var
    posic, enviados, porTransm: word;
    bufinho: array [0..2] of byte;
begin
    bufinho [0] := tipoInfo;
    bufinho [1] := tam and $ff;
    bufinho [2] := (tam shr 8) and $ff;

    enviados := send (sock, @bufinho[0], 3, 0);
    if enviados < 3 then
        begin
            enviaRede := false;
            exit;
        end;

    porTransm := tam;
    posic := 0;
    while porTransm > 0 do
         begin
             enviados := send (sock, @buffer[posic], porTransm, 0);

             if enviados < 1 then
                 begin
                     enviaRede := false;
                     exit;
                 end;
             porTransm := porTransm - enviados;
             posic := posic + enviados;
         end;

    enviaRede := true;
end;

{--------------------------------------------------------}
{               informa o ip desta conexao
{--------------------------------------------------------}

procedure informaIp;
var
    localAddr: sockaddr_in;
    tam: integer;
begin
    fillchar (localAddr, sizeof (localAddr), 0);
    tam := sizeof (localAddr);
    getSockName (sock, localAddr, tam);
    mensagem ('PPNUMIP', 1);   {Número IP desta conexão}
    sintWriteln (strpas (inet_ntoa (localAddr.sin_addr.s_addr)));
end;

end.