Curso de Scripvox - aula13 (Por Fabiano Ferreira).
    Trabalhando com arquivos Parte III

    Nesta aula, completamos a série de comandos para se trabalhar com
arquivos.
    Aprenderemos a buscar por arquivos, copiar, renomear e remover
arquivos já existentes.
    Vamos lá?

*Comando busca;
    Este comando busca por um determinado arquivo, ou por um grupo de
arquivos.
    Forma de uso:
busca variavel  "nomearquivo" ou "*.ext" ou variável.
    Exemplo:
    Busca b "meuarquivo.txt"
    Busca no diretório corrente por um arquivo com o nome
meuarquivo.txt.
    A variável selecionada, no caso a variável b, recebe o nome do
arquivo, caso ele exista, ou um valor em branco, caso o arquivo não
exista.
    Com isso é possível criar um script que procure por um determinado
arquivo ou grupo de arquivo e diga se ele existe ou não... isso vai ser
o exercício de vocês nessa semana.

    Veja agora um outro exemplo:

busca b "*.txt"
    Busca por todos os arquivos, com extenção.txt

Outro exemplo seria:
busca b x, onde x, é uma variável que pode conter um nome de arquivo ou
uma máscara para selecionar um determinado grupo de arquivos.
O conteúdo dessa variável pode ter sido passado via teclado pelo usuário
ou pode ter sido determinado pelo programador em algum ponto do
programa.

    Podemos utilizar, junto ao comando busca, a palavra próximo, para
percorrer uma lista de arquivos, como poderemos observar no script
abaixo:

Escreve "Buscando arquivos de extenção .txt no diretório corrente:"

Busca b "*.txt"

@busca
se b <> ""
Escreve b
busca b próximo
Desvia @busca
senão
termina mudo
Fim se

O script acima começa buscando por arquivos com extenção .txt na pasta
corrente.
    Caso encontre, exibe o nome do arquivo na tela e busca o próximo
arquivo da lista, caso não exista mais arquivos, o programa termina.

    *Comando replica.
    Este comando é utilizado para copiar arquivos.
Forma de uso:
Replica "nomearqantigo" "nomearqnovo"
    Exemplo:

Supondo que exista um arquivo chamado a.txt no diretório corrente,
utilizaremos o seguinte código para tirar uma réplica desse arquivo:

Replica "a.txt" "b.txt"

    O código acima cria um arquivo chamado b.txt, sendo este uma réplica
de a.txt.

    O código abaixo também é válido:

seja $arqantigo "a.txt"
Seja $arqnovo "b.txt"

Replica $arqantigo $arqnovo

    Este faz o mesmo que o primeiro, com a diferença que o nome do
arquivo foi passado através de variável e não diretamente entre aspas.

    Com o comando replica, também é possível copiar um determinado
arquivo para uma outra pasta, assim:

Replica "a.txt" "c:\outrapasta\a.txt"

O código acima replica o arquivo a.txt, com o mesmo nome, salvando na
pasta c:\outrapasta, que no caso, seria uma pasta diferente da que o
usuário está no momento.

*Comando renomeia;
    Este comando renomeia um determinado arquivo.
    Forma de uso:
Renomeia "nomeantigo" "nomenovo"

    Exemplo:

Renomeia "A.txt" "B.txt"

    O exemplo acima troca o nome do arquivo a.txt para b.txt.

    Outro exemplo:

Escreve "Qual o nome do arquivo a renomear"
le $nomeantigo
Escreve "Qual o novo nome?"
Le $nomenovo

Renomeia $nomeantigo $nomenovo

Escreve "Arquivo renomeado para "$nomenovo
Termina mudo

    O programa acima permite que o usuário entre com um nome de arquivo
existente e pergunta pelo novo nome do arquivo.
Em seguida, substitui o nome do arquivo antigo pelo novo nome fornecido.

    *Comando remove;
    Este comando apaga um determinado arquivo.
Forma de uso:
Remove "Nomearquivo"
Exemplo:
Remove "a.txt"
    O exemplo acima remove o arquivo a.txt.

    Agora veja este mesmo exemplo com uma pequena modificação:

Remove "a.txt"&
    Este último exemplo faz a mesma coisa que o anterior.
O e comercial no fim da linha inibe mensagens de erro, caso o programa
não consiga, por algum motivo, remover o arquivo pedido.

    Agora vamos ver outro exemplo:

Escreve "Informe o nome do arquivo a remover:
Lê n
Remove n &
Escreve "arquivo apagado"
Termina mudo

    O exemplo acima pede ao usuário que digite um nome de arquivo e
remove o arquivo com o nome passado pelo usuário.

    Assim terminamos a aula 13 e fechamos os comandos que trabalham com
arquivos, na linguagem scripvox.
    Na próxima aula, veremos os comandos que trabalham com pastas, ou,
como chamamos no dosvox, diretórios.

    Exercício:

Fazer um script com as seguintes características:
*pede ao usuário que informe um nome de arquivo;
*Verificar se o arquivo existe;
*Caso exista, responder ao usuário com uma mensagem positiva do tipo "o
arquivo existe";
*Se o arquivo não existir, responder o usuário com uma mensagem do tipo
"O arquivo não existe".

*Entregar a resposta até o dia 12/11, enviando para o seguinte endereço:
sanfersite@uol.com.br

Boa sorte!
